;================================================================
; common/common_utils 通用工具函数
; utils_html_print.erb HTML_PRINT相关
;================================================================


;;;生成空白占位符
;;;- (option)int width 宽度
;;;@return HTML_PRINT文本
@get_space_html(width=1)
#FUNCTIONS
    #DIM width
    width = ABS(width) > CLIENTWIDTH() / GETCONFIG("フォントサイズ") ? width # width * 100
    RETURNF @"<shape type='space' param='{width}'>"


;;;生成文本 / 按钮
;;;- str text 文本内容
;;;- (option)int style 文本样式(1加粗 2斜体 4删除线 8下划线)
;;;- (option)str color 文本颜色
;;;- (option)str tooltip 鼠标悬浮提示框
;;;- (option)str button 按钮值
;;;- (option)str bcolor 按钮颜色
;;;- (option)str font 文本字体
;;;@return HTML_PRINT文本
@get_text_html(text, style=0, color="", tooltip="", button="", bcolor="", font="")
#FUNCTIONS
    #DIMS text
    #DIM style
    #DIMS color
    #DIMS tooltip
    #DIMS button
    #DIMS bcolor
    #DIMS font
    #DIMS html
    SIF GETBIT(style, 0)
        text '= @"<b>%text%</b>"
    SIF GETBIT(style, 1)
        text '= @"<i>%text%</i>"
    SIF GETBIT(style, 2)
        text '= @"<s>%text%</s>"
    SIF GETBIT(style, 3)
        text '= @"<u>%text%</u>"
    SIF STRFINDU(color, "#") != 0 && COLOR_FROMNAME(color) == -1
        color '= @"#%TOSTR(GETCOLOR(), "x6")%"
    SIF STRFINDU(bcolor, "#") != 0 && COLOR_FROMNAME(bcolor) == -1
        bcolor '= @"#%TOSTR(GETFOCUSCOLOR(), "x6")%"
    SIF !CHKFONT(font)
        font '= GETFONT()
    SIF button == "" && tooltip == ""
        RETURNF @"<font face='%font%' color='%color%' bcolor='%bcolor%'>%text%</font>"
    html '= button == "" ? "<nonbutton" # @"<button value='%button%'"
    html += @" title='%tooltip%'>"
    html += @"<font face='%font%' color='%color%' bcolor='%bcolor%'>%text%</font>"
    html += button == "" ? "</nonbutton>" # "</button>"
    RETURNF html
