;================================================================
; common/common_utils 通用工具函数
; utils_print.erb 打印相关
;================================================================


;;;打印分隔线
;;;@return 没有返回值
@PrintLine()
    PRINTSINGLES DRAWLINESTR
    RETURN


;;;打印日志
;;;- str text 日志文本
;;;- (option)str level 日志等级 默认为info
;;;@return 没有返回值
@PrintLog(text, level="info")
    #DIMS text
    #DIMS level
    level '= TOLOWER(level)
    SELECTCASE level
        CASE "debug"
            SETCOLORBYNAME Gray
        CASE "info"
            SETCOLORBYNAME Cyan
        CASE "warn"
            SETCOLORBYNAME Yellow
        CASE "error", "fail"
            SETCOLORBYNAME Red
        CASE "pass"
            SETCOLORBYNAME Green
        CASEELSE
            SETCOLORBYNAME White
    ENDSELECT
    PRINTSL get_log(text, level)
    RESETCOLOR
    RETURN


;;;获取日志
;;;- str text 日志文本
;;;- (option)str level 日志等级 默认为info
;;;@return 格式化后的日志文本
@get_log(text, level="info")
#FUNCTIONS
    #DIMS text
    #DIMS level
    level '= TOLOWER(level)
    RETURNF @"%GETTIMES()% | %@"%TOUPPER(level)%", 5% | %text%"
